/****************************************
*     JB's Ultra Basic POVRay Demo      *
*	      11-20-2005                *
****************************************/
#include "colors.inc"
#include "woods.inc"
#include "skies.inc"
#include "shapes.inc"

#declare Radiosity = on; // Set to off to speed up test renders (Changes the look quite a bit)
#declare CameraNum = 1; // Set to: (1) In front of table (2) Behind Table (3) Above Table

#declare Dist=100.0; // fade distance for lights

global_settings {
        #if (Radiosity)
                radiosity {
                        pretrace_start 0.08
                        pretrace_end   0.04
                        count 35

                        nearest_count 5
                        error_bound 1.8
                        recursion_limit 3

                        low_error_factor 0.5
                        gray_threshold 0.0
                        minimum_reuse 0.015
                        brightness 1

                        adc_bailout 0.01/2
                }
        #end  
}

#switch (CameraNum)
        #case (1)
        // Front Camera
        camera {
               
                location <10, 4.5, 0>
                direction <0, 0,  2.25>
                look_at <0,0,0>
        }
        #break
        
        #case (2)
        // Back Camera
        camera {
                location <-10, 4.5, 0>
                look_at <0, 0, 0>
        }
        #break
        
        #case (3)
        // Above Table
        camera {
                location <-2.8, 3, 1>
                look_at  <-2.8, 0.5, 0.5>
        }
        #break
#end

/* Lighting */

light_source {
        < 2, 4,  4> color White
        fade_distance Dist fade_power 1
        adaptive 1
}

/*********** Objects ************/
union {
        // Table Top
        object {
                Round_Box(<-1, -0.125, -1>, <1, 0, 1>, 0.1, no) 
     
                texture {
                        tiles {
                                texture {
                                        pigment {
                                                wrinkles
                                                turbulence 1.0
                                                colour_map {
                                                        [0.0 0.7 colour White
                                                                 colour White]
                                                        [0.7 0.9 colour White
                                                                 colour red 0.8 green 0.8 blue 0.8]
                                                        [0.9 1.0 colour red 0.8 green 0.8 blue 0.8
                                                                 colour red 0.5 green 0.5 blue 0.5]
                                                }
                                                scale <0.3, 0.5, 0.3>
                                                rotate -30*y
                                        }
                                        finish {
                                                specular 0.5
                                                roughness 0.02
                                                reflection 0.125
                                        }
                                }
                                tile2
                                        texture {
                                                pigment {
                                                        granite
                                                        scale <0.3, 1, 0.3>
                                                        colour_map {
                                                                [0 1 colour Black
                                                                     colour red 0.5 green 0.5 blue 0.5]
                                                        }
                                                }               
                                                finish {
                                                        specular 0.25
                                                        roughness 0.02
                                                        reflection 0.25
                                                }
                                        }
                                }
                                scale <8, 1, 8>
                        }
                        rotate <180, 0, 0>
                        translate <0, -0.1, 0>
                }
        
        // Table Stand        
        cylinder {
                <0, -0.125, 0>
                <0, -2.5, 0>
                0.125
                texture {
                        pigment {color Black}
                        finish {
                                specular 0.125
                                roughness 1
                                ambient 0.2
                        }
                }
        }
        
        // Table Base
        cone {
                <0, -2.5, 0>, 0.125
                <0, -2.65, 0>, 0.75
                texture {
                        pigment {color Black}
                        finish {
                                specular 0.125
                                roughness 1
                                ambient 0.2
                        }
                }
        }
        translate <-3, 0, 0>                
}


/* Start Bowling Ball */
difference {
        sphere {
                <0.2, 0.5, 0.5> // center of sphere <X Y Z>
                0.5       // radius of sphere
                texture {
                        T_Wood2
                        
                        finish {
                                specular 0.25
                                roughness 0.025
                                ambient 0.2
                        }
                        normal {
                                bumps 0.5
                                scale 0.5
                        }              
                }    
        }
        
        // Index Finger Hole
        cylinder {
                <0.7, 1, 0.5>
                <0.2, 0.5, 0.5>
                0.05
                texture {
                        T_Wood2
                        
                        finish {
                                specular 0.25
                                roughness 0.025
                                ambient 0.2
                        }              
                }
        }

        // Middle Finger        
        cylinder {
                <0.5, 1, 0.3>
                <0.2, 0.5, 0.5>
                0.05
                texture {
                        T_Wood2
                        
                        finish {
                                specular 0.25
                                roughness 0.025
                                ambient 0.2
                        }              
                }
        }
        
        // Thumb
        cylinder {
                <0.2, 1, 0.6>
                <0.2, 0.5, 0.5>
                0.05
                texture {
                        T_Wood2
                        
                        finish {
                                specular 0.25
                                roughness 0.025
                                ambient 0.2
                        }
              
                }
        }
        
        translate <-3, 0, 0>
}


/*********** Scene ************/
// Floor 
cylinder {
        <0, -2.65, 0>,
        <0, -2.70, 0>,
        12
        texture {
                pigment {
                        checker Gray85 Black
                        scale <0.625 0.625 0.625>
                }
                finish {
                        phong 0.5
                }
        }
}


/* Flat Blue Clouds */
sky_sphere {
   pigment {planar colour_map{[0,rgb <0.1,0.9,1>][1, rgb <0.1,0.2,1>]}}
   pigment {
      bozo
      turbulence 0.3
      octaves 6
      omega 0.7
      lambda 2
      color_map {
          [0.0 0.1 color rgb <0.85, 0.85, 0.85>
                   color rgb <0.75, 0.75, 0.75>]
          [0.1 0.5 color rgb <0.75, 0.75, 0.75>
                   color rgbt <1, 1, 1, 1>]
          [0.5 1.0 color rgbt <1, 1, 1, 1>
                   color rgbt <1, 1, 1, 1>]
      }
      scale <0.2, 0.5, 0.2>
    }                     
}